自動実行グループ（AEG）

自動実行グループは、各ツールチェーン タイプに実行プラットフォームを選択します。つまり、実行グループを定義しなくても、1 つのターゲットに複数の実行プラットフォームを設定できます。

要約

自動実行グループはツールチェーンと密接に関連しています。ツールチェーンを使用している場合は、toolchain パラメータを追加して、影響を受けるアクション（ツールチェーンの実行可能ファイルまたはツールを使用するアクション）に設定する必要があります。次に例を示します。

ctx.actions.run(
    ...,
    executable = ctx.toolchain['@bazel_tools//tools/jdk:toolchain_type'].tool,
    ...,
    toolchain = '@bazel_tools//tools/jdk:toolchain_type',
)

アクションがツールチェーンのツールまたは実行可能ファイルを使用しておらず、Blaze がそれを検出しない場合（エラーが発生した場合）、toolchain = None を設定できます。

単一の実行プラットフォームで複数のツールチェーンを使用する必要がある場合（アクションが 2 つ以上のツールチェーンの実行可能ファイルまたはツールを使用する場合）、exec_groups を手動で定義する必要があります（カスタム exec_group を使用する必要があるのはどのような場合ですか？のセクションをご覧ください）。

履歴

AEG の前は、実行プラットフォームはルールレベルで選択されていました。次に例を示します。

my_rule = rule(
    _impl,
    toolchains = ['//tools:toolchain_type_1', '//tools:toolchain_type_2'],
)

ルール my_rule は 2 つのツールチェーン タイプを登録します。つまり、両方のツールチェーン タイプをサポートする実行プラットフォームを見つけるために使用される Toolchain Resolution。exec_groups で別の指定がない限り、選択された実行プラットフォームは、ルール内の登録済みアクションごとに使用されました。つまり、ルール内のすべてのアクションは、異なるツールチェーンのツールを使用している場合でも、単一の実行プラットフォームを使用していました（実行プラットフォームはターゲットごとに選択されます）。これにより、すべてのツールチェーンをサポートする実行プラットフォームがない場合に失敗が発生しました。

現在の状態

AEG では、各ツールチェーン タイプに対して実行プラットフォームが選択されます。前の例の my_rule の実装関数は次のようになります。

def _impl(ctx):
    ctx.actions.run(
      mnemonic = "First action",
      executable = ctx.toolchain['//tools:toolchain_type_1'].tool,
      toolchain = '//tools:toolchain_type_1',
    )

    ctx.actions.run(
      mnemonic = "Second action",
      executable = ctx.toolchain['//tools:toolchain_type_2'].tool,
      toolchain = '//tools:toolchain_type_2',
    )

このルールでは、//tools:toolchain_type_1 の実行可能ファイルを使用する First action と、//tools:toolchain_type_2 の実行可能ファイルを使用する Second action の 2 つのアクションを作成します。AEG の前は、これらのアクションは両方のツールチェーン タイプをサポートする単一の実行プラットフォームで実行されていました。AEG では、アクション内に toolchain パラメータを追加することで、各アクションはツールチェーンを提供する実行プラットフォームで実行されます。アクションは、さまざまな実行プラットフォームで実行される可能性があります。

ctx.actions.run_shell でも同様に、tools がツールチェーンからのものである場合は toolchain パラメータを追加する必要があります。

カスタム実行グループと自動実行グループの違い

名前のとおり、AEG はルールに登録された各ツールチェーン タイプに対して自動的に作成される実行グループです。「従来の」実行グループとは異なり、手動で指定する必要はありません。また、AEG の名前はツールチェーン タイプ（//tools:toolchain_type_1 など）に自動的に設定されます。

カスタム exec_group を使用すべき場合

カスタム exec_groups は、複数のツールチェーンを単一の実行プラットフォームで実行する必要がある場合にのみ必要です。それ以外の場合は、カスタム exec_groups を定義する必要はありません。次に例を示します。

def _impl(ctx):
    ctx.actions.run(
      ...,
      executable = ctx.toolchain['//tools:toolchain_type_1'].tool,
      tools = [ctx.toolchain['//tools:toolchain_type_2'].tool],
      exec_group = 'two_toolchains',
    )

my_rule = rule(
    _impl,
    exec_groups = {
        "two_toolchains": exec_group(
            toolchains = ['//tools:toolchain_type_1', '//tools:toolchain_type_2'],
        ),
    }
)

AEG の移行

google3 の内部では、Blaze はすでに AEG を使用しています。Bazel の外部では、移行が進行中です。一部のルール（Java ルールや C++ ルールなど）では、この機能がすでに使用されています。

この移行をサポートしている Bazel のバージョンはどれですか？

AEG は Bazel 7 以降で完全にサポートされています。

AEG を有効にする方法

--incompatible_auto_exec_groups を true に設定します。フラグの詳細については、GitHub の問題をご覧ください。

特定のルール内で AEG を有効にする方法

ルールに _use_auto_exec_groups 属性を設定します。

my_rule = rule(
    _impl,
    attrs = {
      "_use_auto_exec_groups": attr.bool(default = True),
    }
)

これにより、AEG は my_rule でのみ有効になり、実行プラットフォームを選択すると、アクションは新しいロジックの使用を開始します。互換性のないフラグは、この属性でオーバーライドされます。

エラーが発生した場合に AEG を無効にする方法

--incompatible_auto_exec_groups を false に設定してプロジェクトの AEG を完全に無効にする（フラグの GitHub の問題）、または _use_auto_exec_groups 属性を False に設定して特定のルールを無効にする（属性の詳細）。

AEG への移行中のエラー メッセージ

ツールが暗黙的な依存関係によるものか、ツールチェーンによるものかを特定できませんでした。ツールチェーン パラメータを設定してください。ツールチェーンを使用していない場合は、[None] に設定します。

• この場合、エラーが発生する前の呼び出しのスタックを取得し、ツールチェーン パラメータが必要なアクションを明確に確認できます。アクションに使用されるツールチェーンを確認し、toolchain パラメータで設定します。ツールまたは実行可能ファイルのアクション内でツールチェーンが使用されていない場合は、None に設定します。

存在しないツールチェーン「[toolchain_type]」に対してアクションが宣言されています。

• これは、アクションでツールチェーン パラメータを設定したが、ルールに登録していないことを意味します。ツールチェーンを登録するか、アクション内で None を設定します。

その他の資料

詳細については、設計ドキュメント（ツールチェーンの自動実行グループ）をご覧ください。